多时框动态趋势判断系统：指数移动均线交叉结合相对强弱指数与交易量加权平均价策略

/*backtest
start: 2024-05-13 00:00:00
end: 2025-05-11 08:00:00
period: 1h
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=5
strategy("MinhPhan MA Crossover Strategy RSI 15m + ADX Toggle", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=100, commission_type=strategy.commission.percent, commission_value=0.001)

// === Inputs ===
shortLen = input.int(9, title="Short EMA")
longLen  = input.int(21, title="Long EMA")
useAdxFilter = input.bool(true, title="Enable ADX Filter?")
adxLen = input.int(14, title="ADX Length")
adxThresh = input.float(20, title="Min ADX to Trade")

// === EMAs ===
shortMA = ta.ema(close, shortLen)
longMA = ta.ema(close, longLen)

// === VWAP ===
vwap = ta.vwap

// === RSI from 15-minute timeframe ===
rsi_15m = request.security(syminfo.tickerid, "15", ta.rsi(close, 14))

// === Manual ADX Calculation ===
upMove   = high - high[1]
downMove = low[1] - low

plusDM  = na(upMove) or upMove <= downMove or upMove < 0 ? 0 : upMove
minusDM = na(downMove) or downMove <= upMove or downMove < 0 ? 0 : downMove

tr = math.max(math.max(high - low, math.abs(high - close[1])), math.abs(low - close[1]))

smoothedTR = ta.rma(tr, adxLen)
smoothedPlusDM = ta.rma(plusDM, adxLen)
smoothedMinusDM = ta.rma(minusDM, adxLen)

plusDI = 100 * smoothedPlusDM / smoothedTR
minusDI = 100 * smoothedMinusDM / smoothedTR
dx = 100 * math.abs(plusDI - minusDI) / (plusDI + minusDI)
adx = ta.rma(dx, adxLen)

isTrending = useAdxFilter ? adx > adxThresh : true  // ADX toggle logic

// === VWAP Gap Filter ===
gapThreshold = 0.001
vwapBelowEMAs = 
     (shortMA - vwap) / shortMA > gapThreshold and
     (longMA - vwap) / longMA > gapThreshold

// === Direction Control ===
tradeDirection = input.string(title="Trade Direction", defval="Both", options=["Long", "Short", "Both"])
allowLong = tradeDirection == "Long" or tradeDirection == "Both"
allowShort = tradeDirection == "Short" or tradeDirection == "Both"

// === Entry Conditions ===
if (allowLong and rsi_15m < 30 and isTrending)
    strategy.entry("Long", strategy.long)

if (allowShort and rsi_15m > 30 and ta.crossunder(shortMA, longMA) and vwapBelowEMAs and isTrending)
    strategy.entry("Short", strategy.short)

// === Exit Conditions ===
if (strategy.position_size > 0 and rsi_15m > 70)
    strategy.exit("Exit Long", from_entry="Long", loss=100, profit=200)

if (strategy.position_size < 0 and rsi_15m < 30)
    strategy.exit("Exit Short", from_entry="Short", loss=100, profit=200)

// === Plots ===
plot(shortMA, color=color.blue, title="Short EMA")
plot(longMA, color=color.red, title="Long EMA")
plot(vwap, title="VWAP", color=color.purple, linewidth=2)
plot(adx, title="ADX", color=color.orange)
hline(adxThresh, "ADX Threshold", color=color.gray, linestyle=hline.style_dashed)

• 多指标融合期权销售策略：趋势确认与ATR动态止损优化
• 多重滤网趋势突破智能均线交易策略
• 多周期趋势跟踪与成交量分析的自适应风险策略
• 多周期趋势确认动态风控量化交易策略
• 多指标趋势跟随与动量结合的高级量化交易策略
• 多因子趋势价格行为策略与动态风险管理系统
• 多指标趋势跟踪与区间交易相结合的自适应策略
• 多指标综合分析量化交易策略：趋势动量与波动性协同预测模型
• 多重时间框架动态趋势跟踪策略结合EMA与ADX指标
• 多重指标趋势跟踪增强型量化交易策略