动态波动率适应型趋势交叉交易策略

/*backtest
start: 2024-05-15 00:00:00
end: 2025-05-13 08:00:00
period: 1d
basePeriod: 1d
exchanges: [{"eid":"Futures_Binance","currency":"ETH_USDT"}]
*/

// This Pine Script® code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © vivekm8955

//@version=6
strategy("Simple Trend Signal with SL/TP", overlay=true)

// === INPUTS ===
length            = input.int(10, "Trend Length")
atr_mult          = input.float(1.5, "ATR Multiplier for SL/TP", step=0.1)
supertrend_factor = input.float(3.0, "Supertrend Factor")
supertrend_period = input.int(10, "Supertrend Period")

// === TREND CALC ===
smoothedEma(src, len) =>
    ta.sma(ta.ema(src, len), len)

trendLine   = smoothedEma(close, length)
trendUp     = trendLine > trendLine[1]
trendDn     = trendLine < trendLine[1]
trendChange = trendUp != trendUp[1]
trendColor  = trendUp ? color.lime : trendDn ? color.red : color.gray

// === SUPER TREND ===
atr        = ta.atr(supertrend_period)
upperband  = (high + low) / 2 + supertrend_factor * atr
lowerband  = (high + low) / 2 - supertrend_factor * atr

var float supertrend = na
var bool trend_is_up = true

if na(supertrend)
    supertrend := close > upperband ? lowerband : upperband
    trend_is_up := close > upperband
else
    if close > supertrend
        supertrend := math.max(lowerband, supertrend)
        trend_is_up := true
    else
        supertrend := math.min(upperband, supertrend)
        trend_is_up := false

// === CONDITIONS ===
buySignal  = trendUp and trendChange and trend_is_up
sellSignal = trendDn and trendChange and not trend_is_up

longSL  = close - atr * atr_mult
longTP  = close + atr * atr_mult
shortSL = close + atr * atr_mult
shortTP = close - atr * atr_mult

// === TREND CROSS EXIT CONDITIONS ===
inLongTrade  = strategy.opentrades > 0 and strategy.opentrades.entry_id(0) == "Long"
inShortTrade = strategy.opentrades > 0 and strategy.opentrades.entry_id(0) == "Short"

exitLongOnTrendCross  = inLongTrade and close < trendLine and trendDn
exitShortOnTrendCross = inShortTrade and close > trendLine and trend_is_up

// === STRATEGY EXECUTION ===
if (buySignal)
    strategy.entry("Long", strategy.long, comment="BUY")
    strategy.exit("Long Exit", from_entry="Long", stop=longSL, limit=longTP)

if (sellSignal)
    strategy.entry("Short", strategy.short, comment="SELL")
    strategy.exit("Short Exit", from_entry="Short", stop=shortSL, limit=shortTP)

// Immediate Exit Conditions
if (exitLongOnTrendCross)
    strategy.close("Long", comment="Exit Long: Crossed Below Trend Line")

if (exitShortOnTrendCross)
    strategy.close("Short", comment="Exit Short: Crossed Above Trend Line")

// === PLOTS ===
plot(trendLine, "Trend Line", color=trendColor, linewidth=2)
plot(supertrend, "Supertrend", color=trend_is_up ? color.lime : color.red)

• 基于多维度动态云图的Ichimoku高级多周期交易策略
• 自适应趋势跟踪多周期ATR动态阈值做空策略
• 高级多指标趋势确认交易策略
• ML Alerts Template
• 黑天鹅波动与均线交叉动量跟踪策略
• 三重探底反弹突破动量策略
• 多重指标波动率交易RSI-EMA-ATR策略
• SSL Hybrid
• 多指标趋势动量交叉量化策略
• 多重指标动态自适应调仓ATR波动率策略
• EMA, SMA, CCI, ATR, 均线完美排列策略与趋势魔法指标自动交易系统