হডল লাইন

লেখক:চাওঝাং, তারিখ: ২০-০৫-২০২০২০ঃ৫৮ঃ২৮
ট্যাগঃএইচএমএ

এই সূচকটি ষাঁড়ের বাজারের সময়গুলি নির্ধারণ করে যখন একটি কিনুন এবং ধরে রাখুন বিনিয়োগকারী সম্পদটি ধরে রাখতে পারে এবং হ্রাস বাজারের সময়গুলি যখন তাদের এটি রাখা এড়ানো উচিত। যদিও এটি মূলত ক্রিপ্টোকারেন্সিগুলি মাথায় রেখে ডিজাইন করা হয়েছিল, তবে এটি যে কোনও বাজারের জন্য সফলভাবে ব্যবহার করা যেতে পারে। প্রযুক্তিগতভাবে, সূচকটি একটি অসমত্রিক প্রবণতা ফিল্টার যা এই সত্যকে বিবেচনা করার লক্ষ্যে তৈরি করা হয়েছে যে বাজারের বিক্রয়গুলি আপ-ট্রেন্ডের চেয়ে তীব্র হওয়ার প্রবণতা রয়েছে। অ্যালগরিদমটির দুটি পদ্ধতি রয়েছে মূল্য মসৃণকরণ সহ এবং ছাড়াই।

কিভাবে ব্যবহার করবেন ধাপের মতো লাইনটি মূল প্রবণতা ফিল্টার। এটি একটি আপট্রেন্ডে সবুজ এবং ডাউনট্রেন্ডে লাল রঙের। যখন মসৃণতা চালু থাকে, প্রবণতা ফিল্টারের পাশাপাশি সূচকটি একটি বেগুনি লাইন প্লট করে। এটি দামের একটি হুল মুভিং এভারেজ (এইচএমএ) । এই ক্ষেত্রে, সূচকটি প্রবণতা ফিল্টারের সাথে ক্রসিং খুঁজে পেতে দামের পরিবর্তে এই লাইনটি ব্যবহার করে। যখন দাম বা মসৃণ রেখা উপরে প্রবণতা ফিল্টার অতিক্রম করে, এটি একটি আপট্রেন্ড সংকেত। সূচকটি সবুজ বৃত্ত দিয়ে এই ধরনের ক্রসিং চিহ্নিত করে। এটি একটি আপট্রেন্ডে চার্ট পটভূমিকে সবুজ রঙও দেয়। দাম বা নীচের প্রবণতা ফিল্টারটি অতিক্রম করে বেগুনি রেখা একটি ডাউনট্রেন্ড সংকেত বোঝায়। ডাউনট্রেন্ড সংকেতগুলি লাল বৃত্ত হিসাবে প্রদর্শিত হয়। একটি ডাউনট্রেন্ডে চার্ট পটভূমি লাল হয়ে যায়।

সেটিংস সংবেদনশীলতা একটি ড্রপডাউন তালিকা যা ব্যবহারকারীকে সূচকের গড় সময়কাল চয়ন করতে দেয়। ব্যবহারকারীরা একটি পূর্বনির্ধারিত সেট থেকে সংবেদনশীলতার জন্য একটি মান নির্বাচন করতে পারেন যা তাদের বিনিয়োগের দিগন্তের সাথে আরও ভালভাবে খাপ খায়। ব্যবহার করুন মসৃণকরণ HMA এর সাথে দামের মসৃণকরণ চালু এবং বন্ধ করে দেয়। মসৃণকরণ চালু হওয়ার সাথে সাথে সূচকটি দামের পরিবর্তনের প্রতি ধীর গতিতে প্রতিক্রিয়া জানায়, তবে একই সাথে কম পরিমাণে মিথ্যা সংকেত উত্পাদন করে।

ব্যাকটেস্ট

/*backtest
start: 2022-05-12 00:00:00
end: 2022-05-18 23:59:00
period: 5m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © AstrideUnicorn

// Asymmetrical Trend Filter aka HODL Line

//@version=5
indicator("HODL LINE", overlay=true)

// initialize indicator period parameter and the asymmetry paramter
length = 300
asymmetry =  0.05 //input.float(defval=0.05,step=0.01, minval=0.01, maxval=0.3)

// script inputs
sensitivity = input.string(defval="Hold Short Term", title="Sensitivity", options=['Super Sensitive','Hold Short Term', 'Hold Medium Term', 'Hold Long Term'])
use_smoothing = input.bool(defval=true, title="Use Smoothing")


// Set the indicator period based on the choosen sensitivity 
if sensitivity == 'Super Sensitive'
    length:=50

if sensitivity == 'Hold Short Term'
    length:=100

if sensitivity == 'Hold Medium Term'
    length:=300
    
if sensitivity == 'Hold Long Term'
    length:=500    

// Calculate HODL Line - an assymetric trend filter
HODL_line = (ta.highest(close,length) + ta.lowest(close,length))/(2.0 + asymmetry)

// Calculate smoothed price time series
smoothed_price = ta.hma(close,50)

// Use closing price or smoothed price based on the choosen option for smoothing
price_model = use_smoothing ? smoothed_price : close

// Define conditional color for the HODL Line
hodl_line_color = price_model >= HODL_line ? color.green : color.red

// define the HODL Line crossing conditions
crossing_condition_bull = ta.crossover(price_model, HODL_line)
crossing_condition_bear = ta.crossunder(price_model, HODL_line)

// plotting
plot(HODL_line, color = hodl_line_color, linewidth = 2)

plot(crossing_condition_bull?HODL_line:na, color = color.new(color.green,40), style= plot.style_circles, linewidth = 20)
plot(crossing_condition_bear?HODL_line:na, color = color.new(color.red,40), style= plot.style_circles, linewidth = 20)

bgcolor(color.new(hodl_line_color,80))

plot(use_smoothing?price_model:na, color=color.purple, linewidth=2)

if crossing_condition_bull
    strategy.entry("Enter Long", strategy.long)
else if crossing_condition_bear
    strategy.entry("Enter Short", strategy.short)

সম্পর্কিত

আরো

2019 FMZ - সমস্ত অধিকার সংরক্ষিত