1. Persegi
  2. Maximizer Keuntungan PMax

Maximizer Keuntungan PMax

Penulis:ChaoZhang, Tarikh: 2022-05-25 17:13:45
Tag:SMAEMAWMATMAATRZLEMA

Kedua-dua Indikator MOST dan SuperTrend sangat baik dalam sistem mengikuti trend tetapi sebaliknya prestasi mereka tidak cerah dalam keadaan pasaran sampingan seperti kebanyakan penunjuk lain.

Maximizer keuntungan - PMax cuba menyelesaikan masalah ini. PMax menggabungkan sisi yang kuat MOST (Moving Average Trend Changer) dan SuperTrend (deteksi harga ATR) dalam satu penunjuk.

Hasil ujian belakang dan pengoptimuman PMax jauh lebih baik berbanding dengan nenek moyangnya MOST dan SuperTrend. Ia mengurangkan bilangan isyarat palsu di sisi dan memberikan isyarat perdagangan yang lebih boleh dipercayai.

PMax adalah mudah untuk menentukan trend dan boleh digunakan dalam mana-mana jenis pasaran dan instrumen.

Parameter pertama dalam penunjuk PMax yang ditetapkan oleh tiga parameter adalah tempoh/panjang ATR.

Parameter kedua adalah Pengganda ATR yang berguna untuk menetapkan nilai jarak dari Rata-rata Bergerak yang terbina dalam.

Secara peribadi saya fikir parameter yang paling penting adalah Moving Average Length dan jenis.

PMax akan lebih sensitif terhadap pergerakan trend jika Moving Average Length lebih kecil. dan sebaliknya, akan kurang sensitif apabila ia lebih lama.

Apabila tempoh meningkat ia akan menjadi kurang sensitif kepada trend kecil dan pergerakan harga.

Dengan cara ini, pilihan tempoh anda, akan berkaitan rapat dengan mana jenis trend yang anda minat.

Kami berada di bawah kesan trend menaik dalam kes-kes di mana purata bergerak di atas PMax; sebaliknya di bawah pengaruh trend ke bawah, apabila Purata Bergerak di bawah PMax.

Dibina dalam jenis Moving Average secara lalai ditetapkan sebagai EMA tetapi pengguna boleh memilih dari 8 jenis Moving Average yang berbeza seperti:

SMA: purata bergerak mudah EMA: Purata Bergerak Eksponensial WMA: Purata Bergerak Bertimbang TMA: Purata Bergerak Segitiga VAR: Indeks Berubah Purata Bergerak Dinamik alias VIDYA WWMA: Welles Wilder's Moving Average ZLEMA: Zero Lag Exponential Moving Average TSF: Kekuatan Kekuatan Benar

Petua: Di sisi VAR akan menjadi pilihan yang baik

Anda boleh menggunakan amaran lalai PMax dan isyarat Beli Jual seperti:

1- Beli apabila Moving Average melintasi di atas PMax JUAL apabila Purata Bergerak melintasi di bawah PMax

2- Beli apabila harga melompat di atas garis Pmax. Jual apabila harga turun di bawah garis Pmax.

Ujian belakang

img

/*backtest
start: 2022-04-24 00:00:00
end: 2022-05-23 23:59:00
period: 15m
basePeriod: 5m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

//@version=4
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © KivancOzbilgic
//developer: @KivancOzbilgic
//author: @KivancOzbilgic

study("Profit Maximizer","PMax", overlay=true, format=format.price, precision=2, resolution="")
src = input(hl2, title="Source")
Periods = input(title="ATR Length", type=input.integer, defval=10)
Multiplier = input(title="ATR Multiplier", type=input.float, step=0.1, defval=3.0)
mav = input(title="Moving Average Type", defval="EMA", options=["SMA", "EMA", "WMA", "TMA", "VAR", "WWMA", "ZLEMA", "TSF"])
length =input(10, "Moving Average Length", minval=1)
changeATR= input(title="Change ATR Calculation Method ?", type=input.bool, defval=true)
Normalize= input(title="Normalize ATR ?", type=input.bool, defval=false)
showsupport = input(title="Show Moving Average?", type=input.bool, defval=true)
showsignalsk = input(title="Show Crossing Signals?", type=input.bool, defval=true)
showsignalsc = input(title="Show Price/Pmax Crossing Signals?", type=input.bool, defval=false)
highlighting = input(title="Highlighter On/Off ?", type=input.bool, defval=true)
atr2 = sma(tr, Periods)
atr= changeATR ? atr(Periods) : atr2
valpha=2/(length+1)
vud1=src>src[1] ? src-src[1] : 0
vdd1=src<src[1] ? src[1]-src : 0
vUD=sum(vud1,9)
vDD=sum(vdd1,9)
vCMO=nz((vUD-vDD)/(vUD+vDD))
VAR=0.0
VAR:=nz(valpha*abs(vCMO)*src)+(1-valpha*abs(vCMO))*nz(VAR[1])
wwalpha = 1/ length
WWMA = 0.0
WWMA := wwalpha*src + (1-wwalpha)*nz(WWMA[1])
zxLag = length/2==round(length/2) ? length/2 : (length - 1) / 2
zxEMAData = (src + (src - src[zxLag]))
ZLEMA = ema(zxEMAData, length)
lrc = linreg(src, length, 0)
lrc1 = linreg(src,length,1)
lrs = (lrc-lrc1)
TSF = linreg(src, length, 0)+lrs
getMA(src, length) =>
    ma = 0.0
    if mav == "SMA"
        ma := sma(src, length)
        ma

    if mav == "EMA"
        ma := ema(src, length)
        ma

    if mav == "WMA"
        ma := wma(src, length)
        ma

    if mav == "TMA"
        ma := sma(sma(src, ceil(length / 2)), floor(length / 2) + 1)
        ma

    if mav == "VAR"
        ma := VAR
        ma

    if mav == "WWMA"
        ma := WWMA
        ma

    if mav == "ZLEMA"
        ma := ZLEMA
        ma

    if mav == "TSF"
        ma := TSF
        ma
    ma
    
MAvg=getMA(src, length)
longStop = Normalize ? MAvg - Multiplier*atr/close : MAvg - Multiplier*atr
longStopPrev = nz(longStop[1], longStop)
longStop := MAvg > longStopPrev ? max(longStop, longStopPrev) : longStop
shortStop = Normalize ? MAvg + Multiplier*atr/close : MAvg + Multiplier*atr
shortStopPrev = nz(shortStop[1], shortStop)
shortStop := MAvg < shortStopPrev ? min(shortStop, shortStopPrev) : shortStop
dir = 1
dir := nz(dir[1], dir)
dir := dir == -1 and MAvg > shortStopPrev ? 1 : dir == 1 and MAvg < longStopPrev ? -1 : dir
PMax = dir==1 ? longStop: shortStop
plot(showsupport ? MAvg : na, color=#0585E1, linewidth=2, title="Moving Avg Line")
pALL=plot(PMax, color=color.red, linewidth=2, title="PMax", transp=0)
alertcondition(cross(MAvg, PMax), title="Cross Alert", message="PMax - Moving Avg Crossing!")
alertcondition(crossover(MAvg, PMax), title="Crossover Alarm", message="Moving Avg BUY SIGNAL!")
alertcondition(crossunder(MAvg, PMax), title="Crossunder Alarm", message="Moving Avg SELL SIGNAL!")
alertcondition(cross(src, PMax), title="Price Cross Alert", message="PMax - Price Crossing!")
alertcondition(crossover(src, PMax), title="Price Crossover Alarm", message="PRICE OVER PMax - BUY SIGNAL!")
alertcondition(crossunder(src, PMax), title="Price Crossunder Alarm", message="PRICE UNDER PMax - SELL SIGNAL!")

buySignalk = crossover(MAvg, PMax)
plotshape(buySignalk and showsignalsk ? PMax*0.995 : na, title="Buy", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=color.green, textcolor=color.white, transp=0)

sellSignallk = crossunder(MAvg, PMax)
plotshape(sellSignallk and showsignalsk ? PMax*1.005 : na, title="Sell", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=color.red, textcolor=color.white, transp=0)

buySignalc = crossover(src, PMax)
plotshape(buySignalc and showsignalsc ? PMax*0.995 : na, title="Buy", text="Buy", location=location.absolute, style=shape.labelup, size=size.tiny, color=#0F18BF, textcolor=color.white, transp=0)

sellSignallc = crossunder(src, PMax)
plotshape(sellSignallc and showsignalsc ? PMax*1.005 : na, title="Sell", text="Sell", location=location.absolute, style=shape.labeldown, size=size.tiny, color=#0F18BF, textcolor=color.white, transp=0)

mPlot = plot(ohlc4, title="", style=plot.style_circles, linewidth=0,display=display.none)
longFillColor = highlighting ? (MAvg>PMax ? color.green : na) : na
shortFillColor = highlighting ? (MAvg<PMax ? color.red : na) : na

fill(mPlot, pALL, title="UpTrend Highligter", color=longFillColor)
fill(mPlot, pALL, title="DownTrend Highligter", color=shortFillColor)


if buySignalk
    strategy.entry("Enter Long", strategy.long)
else if sellSignallk
    strategy.entry("Enter Short", strategy.short)
Berkaitan
Lebih lanjut

2019 FMZ - Semua hak dilindungi