RedK वॉल्यूम-एक्सेलेरेटेड दिशात्मक ऊर्जा अनुपात

लेखक:चाओझांग, दिनांकः 2022-05-18 15:21:57
टैगःईएमएएसएमएडब्ल्यूएमए

वॉल्यूम-एक्सेलेरेटेड डायरेक्शनल एनर्जी रेशियो (वीएडीईआर) पर्दे के पीछे सकारात्मक (खरीद) और नकारात्मक (बिक्री) ऊर्जा का अनुमान लगाने के लिए मूल्य आंदोलनों (विस्थापन) और संबंधित वॉल्यूम (प्रयास) का उपयोग करता है, जिससे व्यापारियों को अधिक विस्तार से बाजार की गति को पढ़ने और अपने व्यापारिक निर्णयों को तदनुसार समायोजित करने में सक्षम बनाता है।

VADER कैसे काम करता है?

मैं हमेशा से तकनीकी विश्लेषण की अवधारणाओं का प्रशंसक रहा हूं जो सरल हैं, और जो मूल्य कार्रवाई और मात्रा दोनों को एक साथ एकीकृत करते हैं - VADER के पीछे की अवधारणा वास्तव में एक सरल है।

चलो इसे चलते हैं क्योंकि हम बहुत तकनीकी होने से बचते हैंः बड़ी मात्रा के साथ जुड़े बड़े मूल्य आंदोलनों का अर्थ है कि खरीदार (यदि आंदोलन ऊपर है) या विक्रेता (जब आंदोलन नीचे है) गंभीर हैं और कार्रवाई के नियंत्रण में हैं दूसरी ओर, जब कीमतों में बदलाव छोटे होते हैं लेकिन बड़ी मात्रा में होते हैं, तो इसका मतलब है कि खरीदने और बेचने के बीच एक लड़ाई, या ऊर्जा संतुलन की तुलना में अधिक है। इसके अलावा जब कीमतों में बड़े बदलाव अपेक्षाकृत सीमित मात्रा के साथ जुड़े होते हैं, तो खरीदारों या विक्रेताओं की ऊर्जा की कमी होती है - और ऐसे बदलाव आमतौर पर अल्पकालिक होते हैं।

VADER के साथ सादृश्य यह है कि हम मूल्य आंदोलनों (दो बार के बीच बंद होने का परिवर्तन) को विस्थापन (या कार्रवाई का परिणाम) के रूप में देखते हैं और संबंधित मात्रा को इस कार्रवाई के पीछे प्रयास के रूप में देखते हैं इन 2 मूल्यों को एक साथ मिलाकर, विस्थापन और प्रयास, हमें अंतर्निहित ऊर्जा का प्रतिनिधित्व या एक प्रॉक्सी देता है (एक विशिष्ट दिशा में) । जब दोनों मान (विस्थापन और प्रयास) उच्च होते हैं, तो परिणामी ऊर्जा उच्च होती है - और यदि इनमें से कोई एक मान कम होता है, तो परिणामी ऊर्जा कम होती है।

फिर हम प्रत्येक दिशा में उस सापेक्ष ऊर्जा का औसत लेते हैं (सकारात्मक = खरीद और नकारात्मक = बिक्री) और शुद्ध ऊर्जा की गणना करते हैं।

ध्यान दें कि हम यहाँ एक व्यापारिक परिप्रेक्ष्य से और भौतिकी के परिप्रेक्ष्य से नहीं सादृश्य के करीब आ रहे हैं:) हम क्षमा किया जा सकता है अगर भौतिकी में ऊर्जा गणना अलग है...

बैकटेस्ट

img


/*backtest
start: 2022-04-17 00:00:00
end: 2022-05-16 23:59:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © RedKTrader

//@version=5
indicator('RedK Volume-Accelerated Directional Energy Ratio', 'RedK VADER v3.0', precision=0, timeframe='', timeframe_gaps=false)

// ***********************************************************************************************************
// Choose volume calculation method.. Relative vs full. 
// Relative magnifies effect of recent volume spikes (up or down) 
f_RelVol(_value, _length) =>
    min_value = ta.lowest(_value, _length)
    max_value = ta.highest(_value, _length)
    ta.stoch(_value, max_value, min_value, _length) / 100
// ***********************************************************************************************************

// ***********************************************************************************************************
// Choose MA type for the base DER calculation .. 
// WMA is my preference and is default .. SMA is really slow and lags a lot - but added for comparison
f_derma(_data, _len, MAOption) =>
    value = 
      MAOption == 'SMA' ? ta.sma(_data, _len) :
      MAOption == 'EMA' ? ta.ema(_data, _len) :
      ta.wma(_data, _len)
// ***********************************************************************************************************


// ===========================================================================================================
//      Inputs
// ===========================================================================================================

price   = close
length  = input.int(9, minval=1)
DER_avg = input.int(5, 'Average', minval=1, inline='DER', group='Directional Energy Ratio')
MA_Type = input.string('WMA', 'DER MA type', options=['WMA', 'EMA', 'SMA'], inline='DER', group='Directional Energy Ratio') 
smooth  = input.int(3, 'Smooth', minval=1,  inline='DER_1', group='Directional Energy Ratio')

show_senti = input.bool(false, 'Sentiment',  inline='DER_s', group='Directional Energy Ratio')
senti   = input.int(20, 'Length', minval=1, inline='DER_s', group='Directional Energy Ratio')


v_calc  = input.string('Relative', 'Calculation', options=['Relative', 'Full', 'None'], group='Volume Parameters')
vlookbk = input.int(10, 'Lookback (for Relative)', minval=1,                            group='Volume Parameters')

// ===========================================================================================================
//          Calculations
// ===========================================================================================================

// Volume Calculation Option  -- will revert to no volume acceleration for instruments with no volume data
vola    = 
  v_calc == 'None' or na(volume) ? 1 : 
  v_calc == 'Relative' ? f_RelVol(volume, vlookbk) : 
  volume

R       = (ta.highest(2) - ta.lowest(2)) / 2                    // R is the 2-bar average bar range - this method accomodates bar gaps
sr      = ta.change(price) / R                                  // calc ratio of change to R
rsr     = math.max(math.min(sr, 1), -1)                         // ensure ratio is restricted to +1/-1 in case of big moves
c       = fixnan(rsr * vola)                                    // add volume accel -- fixnan adresses cases where no price change between bars

c_plus  = math.max(c, 0)                                        // calc directional vol-accel energy
c_minus = -math.min(c, 0)

// plot(c_plus)
// plot(c_minus)


avg_vola    = f_derma(vola, length, MA_Type)
dem         = f_derma(c_plus, length, MA_Type)  / avg_vola          // directional energy ratio
sup         = f_derma(c_minus, length, MA_Type) / avg_vola

adp         = 100 * ta.wma(dem, DER_avg)                            // average DER
asp         = 100 * ta.wma(sup, DER_avg)
anp         = adp - asp                                             // net DER..
anp_s       = ta.wma(anp, smooth)

// Calculate Sentiment - a VADER for a longer period and can act as a baseline (compared to a static 0 value)
// note we're not re-calculating vol_avg, demand or supply energy for sentiment. this would've been a different approach
s_adp       = 100 * ta.wma(dem, senti)                            // average DER for sentiment length
s_asp       = 100 * ta.wma(sup, senti)
V_senti     = ta.wma(s_adp - s_asp, smooth)


// ===========================================================================================================
//      Colors & plots
// ===========================================================================================================
c_adp   = color.new(color.aqua, 30)
c_asp   = color.new(color.orange, 30)
c_fd    = color.new(color.green, 80)
c_fs    = color.new(color.red, 80)
c_zero  = color.new(#ffee00, 70)

c_up    = color.new(#359bfc, 0)
c_dn    = color.new(#f57f17, 0)

c_sup   = color.new(#33ff00, 80)
c_sdn   = color.new(#ff1111, 80)
up      = anp_s >= 0
s_up    = V_senti >=0 

hline(0, 'Zero Line', c_zero, hline.style_solid)

// =============================================================================
// v3.0 --- Sentiment will be represented as a 4-color histogram
c_grow_above = #1b5e2080 
c_grow_below = #dc4c4a80
c_fall_above = #66bb6a80  
c_fall_below = #ef8e9880     

sflag_up = math.abs(V_senti) >= math.abs(V_senti[1])

plot(show_senti ? V_senti : na, "Sentiment", style=plot.style_columns, 
 color = s_up ? (sflag_up ? c_grow_above : c_fall_above) : 
 sflag_up ? c_grow_below : c_fall_below) 
// =============================================================================

s = plot(asp, 'Supply Energy', c_asp, 2, style=plot.style_circles,  join=true)
d = plot(adp, 'Demand Energy', c_adp, 2, style=plot.style_cross,    join=true)
fill(d, s, adp > asp ? c_fd : c_fs)

plot(anp, 'VADER', color.new(color.gray, 30), display=display.none)
plot(anp_s, 'Signal', up ? c_up : c_dn, 3)

// ===========================================================================================================
//      v2.0 adding alerts 
// ===========================================================================================================

Alert_up    = ta.crossover(anp_s,0)
Alert_dn    = ta.crossunder(anp_s,0)
Alert_swing = ta.cross(anp_s,0)

// "." in alert title for the alerts to show in the right order up/down/swing 
alertcondition(Alert_up,    ".   VADER Crossing 0 Up",      "VADER Up - Buying Energy Detected!")
alertcondition(Alert_dn,    "..  VADER Crossing 0 Down",    "VADER Down - Selling Energy Detected!")
alertcondition(Alert_swing, "... VADER Crossing 0",         "VADER Swing - Possible Reversal")

// ===========================================================================================================
//      v3.0 more alerts for VADER crossing Sentiment
// ===========================================================================================================

v_speedup = ta.crossover(anp_s, V_senti)
v_slowdn  = ta.crossunder(anp_s, V_senti)
alertcondition(v_speedup,   "*  VADER Speeding Up",      "VADER Speeding Up!")
alertcondition(v_slowdn,    "** VADER Slowing Down",    "VADER Slowing Down!")




if Alert_up
    strategy.entry("Enter Long", strategy.long)
else if Alert_dn
    strategy.entry("Enter Short", strategy.short)

संबंधित

अधिक