双方向モメンタムストッププロフィットおよびストップロス戦略

作成日: 2024-01-08 11:58:21 最終変更日: 2024-01-08 11:58:21

コピー: 0 クリック数: 770

ChaoZhang

フォローダイレクトメッセージ

フォロー

1617

フォロワー

双方向モメンタムストッププロフィットおよびストップロス戦略

概要

この戦略は,TradingViewの内蔵された連続した上下策の拡張である. これは,逆転取引を行うための柔軟な戦略方向設定を有している. 同時に,多種な停止方法,例えば,揺動高点/低点,ATRの停止と追跡停止,および対応する停止設定を統合している. これは,この戦略を元の取引信号の基礎に維持し,より良いリスク管理を得ることを可能にする.

戦略原則

この戦略は,主にK線が連続して上昇または下降する回数を判断して,買入と売却のシグナルを生成する.ユーザーは,買入のシグナルを生成するために必要な連続した上昇K線の数と,売出のシグナルに必要な連続した下降K線の数を設定することができます.

同時に,戦略は逆転取引の設定を追加した.逆転取引を開始すると,元の買入シグナルが売り込みシグナルに変化し,売り込みシグナルも買入シグナルに変化し,取引の逆転が完了した.

入場と退出において,戦略は直接逆平仓を支えている.この方法で,無ポジションで取引できない状況を減らすことができる.

ストップとストップに関して,戦略は,高点/低点,ATRと戦略の内蔵の3つの選択可能なストップ方法を提供している.ストップ方法は,ポジションの方向と組み合わせて,自動で最下谷または最高峰を激進的なストップポイントとして選択するか,ATRの動向に基づいてストップ価格を決定する.ストップセットは,戦略のエントリー価格を基準として,固定倍数のストップ距離を設定する.

ストップトラッキングを有効にすると,戦略は損失時にストップスラップを大きくし,利益時にストップスラップを小さく,自動トラッキングを実現する.

優位分析

この戦略の最大の利点は,異なる市場状況に適応する柔軟性があることです.具体的には以下の通りです.

トレンドと振動に適応する,設定可能な買取りフィルターパラメータ
需要に応じて方向を選択できる
直接逆開設を設定し,無ポジション期を減らす
複数のストップ方式を統合し,必要に応じて選択できます.
追跡可能な停止,自動停止

リスク分析

この戦略の主なリスクは,連続したK線を過剰に設定することで,見逃した取引機会を引き起こす可能性があること,そして,ストップ・ローズを過剰に激進的に設定することで,損失の拡大が起こるというリスクである. リスクに対する勧告は以下の通りである.

K線数値の上昇/下降のパラメータを調整し,過度に過激にしないでください
テストして,最も適したものを選択します.
ストップトラッキングは,過度の損失を避けるために慎重に設定します.

最適化の方向

この戦略は,さらに改善できる余地があります.

ATRや波動率などの指標に基づいて動的に調整できる上下K線数
異なるポジション保有期間におけるストップ・ストップ・ストップ比率パラメータの効果をテストできる
Open フィルターを設定して,偽侵入を防ぐことができます.
信号の質を高めるために,他の補助指標の判断を加えることができます.

要約する

この戦略は,基准戦略の有益な拡張であり,リスクをより良く管理し,より柔軟な取引方法を得ることができます. これは,最適化しやすい実用的な効果的なモメンタム戦略です.

ストラテジーソースコード

/*backtest
start: 2023-01-07 00:00:00
end: 2023-08-30 05:20:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// Extension of the built-in strategy by Tradingview. The strategy buys after an X amount of
// consecutive bullish bars and viceversa for selling. This logic can be reversed and a Stop Loss
// with Take Profit can be added. There's also an option to adapt the SL into a Trailing Stop.

//@version=4
strategy("Consecutive Up/Down Strategy with Reverse", 
     overlay=true, 
     default_qty_type=strategy.percent_of_equity, 
     default_qty_value=100, 
     initial_capital=10000, 
     commission_value=0.04, 
     calc_on_every_tick=false, 
     slippage=0)

direction = input(0, title = "Strategy Direction", type=input.integer, minval=-1, maxval=1)
strategy.risk.allow_entry_in(direction == 0 ? strategy.direction.all : (direction < 0 ? strategy.direction.short : strategy.direction.long))

/////////////////////// STRATEGY INPUTS ////////////////////////////////////////
title1=input(true, "-----------------Strategy Inputs-------------------")  

consecutiveBarsUp = input(3)
consecutiveBarsDown = input(4)

/////////////////////// BACKTESTER /////////////////////////////////////////////
title2=input(true, "-----------------General Inputs-------------------")  

// Backtester General Inputs
i_SL=input(true, title="Use Stop Loss and Take Profit")
i_SLType=input(defval="ATR Stop", title="Type Of Stop", options=["Strategy Stop", "Swing Lo/Hi", "ATR Stop"])
i_SPL=input(defval=10, title="Swing Point Lookback")
i_PercIncrement=input(defval=2, step=.1, title="Swing Point SL Perc Increment")*0.01
i_ATR = input(14, title="ATR Length")
i_ATRMult = input(5, step=.1, title="ATR Multiple")
i_TPRRR = input(5, step=.1, title="Take Profit Risk Reward Ratio")
TS=input(true, title="Trailing Stop")

// Bought and Sold Boolean Signal
bought = strategy.position_size > strategy.position_size[1] 
 or strategy.position_size < strategy.position_size[1]

// Price Action Stop and Take Profit
LL=(lowest(i_SPL))*(1-i_PercIncrement)
HH=(highest(i_SPL))*(1+i_PercIncrement)
LL_price = valuewhen(bought, LL, 0)
HH_price = valuewhen(bought, HH, 0)
entry_LL_price = strategy.position_size > 0 ? LL_price : na 
entry_HH_price = strategy.position_size < 0 ? HH_price : na 
tp=strategy.position_avg_price + (strategy.position_avg_price - entry_LL_price)*i_TPRRR
stp=strategy.position_avg_price - (entry_HH_price - strategy.position_avg_price)*i_TPRRR

// ATR Stop
ATR=atr(i_ATR)*i_ATRMult
ATRLong = ohlc4 - ATR
ATRShort = ohlc4 + ATR
ATRLongStop = valuewhen(bought, ATRLong, 0)
ATRShortStop = valuewhen(bought, ATRShort, 0)
LongSL_ATR_price = strategy.position_size > 0 ? ATRLongStop : na 
ShortSL_ATR_price = strategy.position_size < 0 ? ATRShortStop : na 
ATRtp=strategy.position_avg_price + (strategy.position_avg_price - LongSL_ATR_price)*i_TPRRR
ATRstp=strategy.position_avg_price - (ShortSL_ATR_price - strategy.position_avg_price)*i_TPRRR


// Strategy Stop
float LongStop = na
float ShortStop = na
float StratTP = na
float StratSTP = na

/////////////////////// STRATEGY LOGIC /////////////////////////////////////////

price = close
ups = 0.0
ups := price > price[1] ? nz(ups[1]) + 1 : 0
dns = 0.0
dns := price < price[1] ? nz(dns[1]) + 1 : 0

BUY=ups >= consecutiveBarsUp and bar_index > 40
SELL=dns >= consecutiveBarsDown and bar_index > 40

//Trading Inputs
DPR=input(true, "Allow Direct Position Reverse")
reverse=input(false, "Reverse Trades")

// Entries
if reverse
    if not DPR
        strategy.entry("long", strategy.long, when=SELL and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=BUY and strategy.position_size == 0)
    else     
        strategy.entry("long", strategy.long, when=SELL)
        strategy.entry("short", strategy.short, when=BUY)
else
    if not DPR 
        strategy.entry("long", strategy.long, when=BUY and strategy.position_size == 0)
        strategy.entry("short", strategy.short, when=SELL and strategy.position_size == 0)
    else
        strategy.entry("long", strategy.long, when=BUY)
        strategy.entry("short", strategy.short, when=SELL)
        



SL= i_SLType == "Swing Lo/Hi" ? entry_LL_price : i_SLType == "ATR Stop" ? LongSL_ATR_price : LongStop
SSL= i_SLType == "Swing Lo/Hi" ? entry_HH_price : i_SLType == "ATR Stop" ? ShortSL_ATR_price : ShortStop
TP= i_SLType == "Swing Lo/Hi" ? tp : i_SLType == "ATR Stop" ? ATRtp : StratTP
STP= i_SLType == "Swing Lo/Hi" ? stp : i_SLType == "ATR Stop" ? ATRstp : StratSTP

//TrailingStop
dif=(valuewhen(strategy.position_size>0 and strategy.position_size[1]<=0, high,0))
 -strategy.position_avg_price
trailOffset     = strategy.position_avg_price - SL
var tstop = float(na)
if strategy.position_size > 0
    tstop := high- trailOffset - dif
    if tstop<tstop[1]
        tstop:=tstop[1]
else
    tstop := na
StrailOffset     = SSL - strategy.position_avg_price
var Ststop = float(na)
Sdif=strategy.position_avg_price-(valuewhen(strategy.position_size<0 
 and strategy.position_size[1]>=0, low,0))
if strategy.position_size < 0
    Ststop := low+ StrailOffset + Sdif
    if Ststop>Ststop[1]
        Ststop:=Ststop[1]
else
    Ststop := na

strategy.exit("TP & SL", "long", limit=TP, stop=TS? tstop : SL, when=i_SL)
strategy.exit("TP & SL", "short", limit=STP, stop=TS? Ststop : SSL, when=i_SL)

/////////////////////// PLOTS //////////////////////////////////////////////////


plot(i_SL and strategy.position_size > 0 and not TS ? SL : i_SL and strategy.position_size > 0 and TS ? tstop : na , title='SL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size < 0 and not TS ? SSL : i_SL and strategy.position_size < 0 and TS ? Ststop : na , title='SSL', style=plot.style_cross, color=color.red)
plot(i_SL and strategy.position_size > 0 ? TP : na, title='TP', style=plot.style_cross, color=color.green)
plot(i_SL and strategy.position_size < 0 ? STP : na, title='STP', style=plot.style_cross, color=color.green)
// Draw price action setup arrows
plotshape(BUY ? 1 : na, style=shape.triangleup, location=location.belowbar, 
 color=color.green, title="Bullish Setup", size=size.auto)
plotshape(SELL ? 1 : na, style=shape.triangledown, location=location.abovebar, 
 color=color.red, title="Bearish Setup", size=size.auto)

Forums

PINE Language FAQ Summary MyLanguage Web3 About Us

Product

Robot Strategy Node Platforms Tickets

API

Syntax guide User guide Trading api Blockchain Indicator