Двухэтапная стратегия остановки потерь

Автор:Чао Чжан, Дата: 2023-10-25 18:11:30
Тэги:

Обзор

Основная идея этой стратегии заключается в том, чтобы установить две цели получения прибыли и переместить стоп-лосс на цену входа после достижения первой цели, чтобы избежать охоты на стоп-лосс.

Логика стратегии

Эта стратегия включает в себя сделки, основанные на диапазонах Боллинджера и стохастических показателях.

В частности, логика ввода:

Введите длинный, когда закрытие находится ниже нижней полосы Боллинджера и стохастический К пересекает ниже D.
Вход в короткий период, когда закрытие находится выше верхней полосы Боллинджера и стохастический К пересекает выше D.

Стратегия устанавливает две цели получения прибыли, TP1 - 200 пунктов и TP2 - 500 пунктов.

Когда цена движется и TP1 запускается, стратегия перемещает стоп-лосс на цену входа. Это блокирует прибыль с первой стадии и предотвращает охоту на стоп-лосс.

Стратегия закрывает все позиции при запуске TP2 или стоп-лосса.

Анализ преимуществ

Самое большое преимущество этого двухступенчатого подхода стоп-лосса заключается в том, что он позволяет блокировать прибыль, предотвращая при этом охоту на стоп-лосс.

Еще одно преимущество заключается в сочетании полос Боллинджера для измерения диапазона волатильности и стохастического показателя для перекупленных/перепроданных данных, что обеспечивает более точные записи.

Анализ рисков

Основные риски возникают из потенциальных ложных сигналов от полос Боллинджера и стохастических индикаторов. Неправильный диапазон Боллинджера может привести к отсутствию записей или плохим сигналам.

Существует также риск того, что стоп-лосс будет снова выигран после перехода на входную цену.

Эти риски могут быть уменьшены путем оптимизации параметров для обоих показателей и увеличения расстояния между остановками потерь.

Руководство по оптимизации

Дальнейшие оптимизации этой стратегии:

Испытывайте различные комбинации параметров, чтобы найти оптимальные параметры Боллинджера и Стохастики.
Проверьте различные цели прибыли/убытка, чтобы найти идеальную конфигурацию.
Добавьте другие показатели, такие как скользящие средние, чтобы создать многоиндикаторные системы для более высокой точности.
Исследуйте альтернативную логику позиционирования стоп-лосса, например, фиксированное расстояние от входа вместо самой цены входа.
Увеличить количество движений стоп-лосса до 3 или более этапов.

Заключение

Эта стратегия использует полосы Боллинджера и стохастик для входов, устанавливает две цели получения прибыли и перемещает стоп-лосс на вход после достижения первой цели, чтобы сформировать двухступенчатую стоп-лосс. Это эффективно блокирует прибыль и предотвращает охоту на стоп-лосс. Стратегия имеет явные преимущества, но также имеет место для улучшений с помощью оптимизации параметров, мультииндикаторных систем и корректировки логики стоп-лосса.

/*backtest
start: 2022-10-18 00:00:00
end: 2023-10-24 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © fpsd4ve

//@version=5

// Add Bollinger Bands indicator (close, 20, 2) manually to visualise trading conditions
strategy("2xTP, SL to entry", 
     overlay=false,
     pyramiding=0,
     calc_on_every_tick=false,
     default_qty_type=strategy.percent_of_equity,
     default_qty_value=25,
     initial_capital=1000,
     commission_type=strategy.commission.percent,
     commission_value=0.01
     )

// PARAMETERS
// Assumes quote currency is FIAT as with BTC/USDT pair
tp1=input.float(200, title="Take Profit 1")
tp2=input.float(500, title="Take Profit 2")
sl=input.float(200, title="Stop Loss")
stOBOS = input.bool(true, title="Use Stochastic overbought/oversold threshold")

// Colors
colorRed = #FF2052
colorGreen = #66FF00


// FUNCTIONS
// Stochastic
f_stochastic() =>
    stoch = ta.stoch(close, high, low, 14)
    stoch_K = ta.sma(stoch, 3)
    stoch_D = ta.sma(stoch_K, 3)
    stRD = ta.crossunder(stoch_K, stoch_D)
    stGD = ta.crossover(stoch_K, stoch_D)
    [stoch_K, stoch_D, stRD, stGD]


// VARIABLES
[bbMiddle, bbUpper, bbLower] = ta.bb(close, 20, 2)
[stoch_K, stoch_D, stRD, stGD] = f_stochastic()


// ORDERS
// Active Orders
// Check if strategy has open positions
inLong = strategy.position_size > 0
inShort = strategy.position_size < 0
// Check if strategy reduced position size in last bar
longClose = strategy.position_size < strategy.position_size[1]
shortClose = strategy.position_size > strategy.position_size[1]

// Entry Conditions
// Enter long when during last candle these conditions are true:
// Candle high is greater than upper Bollinger Band
// Stochastic K line crosses under D line and is oversold
longCondition = stOBOS ?
     low[1] < bbLower[1] and stGD[1] and stoch_K[1] < 25 :
     low[1] < bbLower[1] and stGD[1]

// Enter short when during last candle these conditions are true:
// Candle low is lower than lower Bollinger Band
// Stochastic K line crosses over D line and is overbought
shortCondition = stOBOS ?
     high[1] > bbUpper[1] and stRD[1] and stoch_K[1] > 75 :
     high[1] > bbUpper[1] and stRD[1]

// Exit Conditions
// Calculate Take Profit 
longTP1 = strategy.position_avg_price + tp1
longTP2 = strategy.position_avg_price + tp2
shortTP1 = strategy.position_avg_price - tp1
shortTP2 = strategy.position_avg_price - tp2

// Calculate Stop Loss
// Initialise variables
var float longSL = 0.0
var float shortSL = 0.0

// When not in position, set stop loss using close price which is the price used during backtesting
// When in a position, check to see if the position was reduced on the last bar
// If it was, set stop loss to position entry price. Otherwise, maintain last stop loss value
longSL := if inLong and ta.barssince(longClose) < ta.barssince(longCondition)
    strategy.position_avg_price
else if inLong
    longSL[1]
else
    close - sl

shortSL := if inShort and ta.barssince(shortClose) < ta.barssince(shortCondition)
    strategy.position_avg_price
else if inShort
    shortSL[1]
else
    close + sl

// Manage positions
strategy.entry("Long", strategy.long, when=longCondition)
strategy.exit("TP1/SL", from_entry="Long", qty_percent=50, limit=longTP1, stop=longSL)
strategy.exit("TP2/SL", from_entry="Long", limit=longTP2, stop=longSL)

strategy.entry("Short", strategy.short, when=shortCondition)
strategy.exit("TP1/SL", from_entry="Short", qty_percent=50, limit=shortTP1, stop=shortSL)
strategy.exit("TP2/SL", from_entry="Short", limit=shortTP2, stop=shortSL)


// DRAW
// Stochastic Chart
plot(stoch_K, color=color.blue)
plot(stoch_D, color=color.orange)

// Circles
plot(stOBOS ? stRD and stoch_K >= 75 ? stoch_D : na : stRD ? stoch_D : na, color=colorRed, style=plot.style_circles, linewidth=3)
plot(stOBOS ? stGD and stoch_K <= 25 ? stoch_D : na : stGD ? stoch_K : na, color=colorGreen, style=plot.style_circles, linewidth=3)

// Levels
hline(75, linestyle=hline.style_dotted)
hline(25, linestyle=hline.style_dotted)

Больше