Стратегия двойного выхода

Автор:Чао Чжан, Дата: 2023-11-03 17:16:02
Тэги:

Обзор

Эта стратегия использует полосы Боллинджера для выявления точек выхода для длинных и коротких сделок в сочетании с индикатором ADX для фильтрации неблагоприятных рыночных условий с низкой волатильностью, чтобы следовать тенденциям.

Логика стратегии

Стратегия в основном основана на индикаторе Болинджерских полос для определения длинного или короткого направления. Средняя полоса Болинджерских полос представляет собой N-дневную скользящую среднюю цену закрытия, а ширина полосы рассчитывается с использованием стандартного отклонения.

Для того, чтобы избежать недействительных прорывов и ошибочных сделок на нестабильных рынках, стратегия включает в себя индикатор ADX для фильтрации условий рынка с низкой волатильностью.

Стратегия также устанавливает последующие стоп-лосс и прибыль для открытых сделок. В частности, после открытия позиции, самая низкая цена и самая высокая цена предыдущих N дней регистрируются как стоп-лосс и уровни прибыли для этого направления. Это позволяет зафиксировать прибыль, сокращая при этом потери от обратных сделок.

С логики кода стратегия сначала рассчитывает диапазоны Боллинджера и параметры ADX. Затем она проверяет, прорывает ли цена верхнюю или нижнюю полосу диапазонов, и если ADX ниже порога, чтобы генерировать торговые сигналы. После этого уровни остановки потери и получения прибыли динамически обновляются и отслеживаются на основе направления текущей позиции.

Анализ преимуществ

Боллингерские полосы предлагают четкие сигналы прорыва для поимки трендовых возможностей
ADX-фильтр избегает торговли Рыночные перебои без четких тенденций
Стоп-лосс эффективно контролирует потерю на одной сделке
Задержка прибыли в большинстве прибылей

Анализ рисков

Прорывы могут быть ложными без учета объема
ADX фильтр также может упустить трендовые возможности
Стоп-потеря и получение прибыли слишком близко могут быть остановлены
Плохая настройка параметров влияет на эффективность стратегии

Подумайте о сочетании с другими индикаторами, чтобы подтвердить прорыв с объемом; оптимизируйте фильтр ADX с использованием наклона для выявления изменений тренда; расширите диапазон стоп-лосса и прибыли, чтобы избежать преждевременного выхода.

Направления к улучшению

Оптимизировать длину полос Боллинджера для достижения лучших результатов прорыва
Фино настроенный ADX фильтр для баланса точности тренда и ложных сигналов
Добавить другие показатели для подтверждения действительности прорыва
Оптимизировать диапазон остановки потери для предотвращения чрезмерной чувствительности
Расширить диапазон получения прибыли, чтобы получить больше прибыли

Заключение

Стратегия имеет ясную и простую логику, используя полосы Боллинджера для очевидных сигналов прорыва, отфильтрованные ADX для условий тренда, для захвата трендовых возможностей.

/*backtest
start: 2023-10-26 00:00:00
end: 2023-11-02 00:00:00
period: 1m
basePeriod: 1m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// © tweakerID

// This strategy uses Bollinger Bands to buy when the price 
// crosses over the lower band and sell when it crosses down
// the upper band. It only takes trades when the ADX is 
// below a certain level, and exits all trades when it's above it.

//@version=4
strategy("BB + ADX Strategy", overlay=true, default_qty_type=strategy.percent_of_equity, default_qty_value=100, commission_value = 0.04, initial_capital=100)

//Inputs
i_reverse=input(false, title="Reverse Trades")
i_ADXClose=input(true, title="ADX Close")
i_SL=input(false, title="Use Swing Lo/Hi Stop Loss & Take Profit")
i_SwingLookback=input(20, title="Swing Lo/Hi Lookback")
i_SLExpander=input(defval=0, step=.5, title="SL Expander")
i_TPExpander=input(defval=0, step=.5, title="TP Expander")

//ADX Calculations
adxlen = input(14, title="ADX Smoothing")
dilen = input(20, title="DI Length")
dirmov(len) =>
	up = change(high)
	down = -change(low)
	plusDM = na(up) ? na : (up > down and up > 0 ? up : 0)
	minusDM = na(down) ? na : (down > up and down > 0 ? down : 0)
	truerange = rma(tr, len)
	plus = fixnan(100 * rma(plusDM, len) / truerange)
	minus = fixnan(100 * rma(minusDM, len) / truerange)
	[plus, minus]
adx(dilen, adxlen) =>
	[plus, minus] = dirmov(dilen)
	sum = plus + minus
	adx = 100 * rma(abs(plus - minus) / (sum == 0 ? 1 : sum), adxlen)
sig = adx(dilen, adxlen)
adxlevel=input(30, step=5)

//BB Calculations
BBCALC=input(false, title="-----------BB Inputs-----------")

length = input(20, minval=1)
mult = input(2.0, minval=0.001, maxval=50)
MAlen=input(defval=9)
source = close
basis = sma(source, length)
dev = mult * stdev(source, length)
upper = basis + dev
lower = basis - dev

//Entry Logic
BUY = crossover(source, lower) and sig < adxlevel
SELL = crossunder(source, upper) and sig < adxlevel

//SL & TP Calculations
SwingLow=lowest(i_SwingLookback)
SwingHigh=highest(i_SwingLookback)
bought=strategy.position_size != strategy.position_size[1]
LSL=valuewhen(bought, SwingLow, 0)-((valuewhen(bought, atr(14), 0))*i_SLExpander)
SSL=valuewhen(bought, SwingHigh, 0)+((valuewhen(bought, atr(14), 0))*i_SLExpander)
lTP=strategy.position_avg_price + (strategy.position_avg_price-(valuewhen(bought, SwingLow, 0))+((valuewhen(bought, atr(14), 0))*i_TPExpander))
sTP=strategy.position_avg_price - (valuewhen(bought, SwingHigh, 0)-strategy.position_avg_price)-((valuewhen(bought, atr(14), 0))*i_TPExpander)
islong=strategy.position_size > 0
isshort=strategy.position_size < 0
SL= islong ? LSL : isshort ? SSL : na
TP= islong ? lTP : isshort ? sTP : na

//Entries
strategy.entry("long", long=i_reverse?false:true, when=BUY)
strategy.entry("short", long=i_reverse?true:false, when=SELL)

//EXITS
if i_ADXClose
    strategy.close_all(when=sig > adxlevel)
if i_SL
    strategy.exit("longexit", "long", stop=SL, limit=TP)
    strategy.exit("shortexit", "short", stop=SL, limit=TP)

//Plots	
plot(i_SL ? SL : na, color=color.red, style=plot.style_cross, title="SL")
plot(i_SL ? TP : na, color=color.green, style=plot.style_cross, title="TP")
plot(upper)
plot(lower)

Больше