1. Quảng trường
  2. Chiến lược theo dõi động lực

Chiến lược theo dõi động lực

Tác giả:ChaoZhang, Ngày: 2023-12-29 16:26:49
Tags:

img

Tổng quan

Chiến lược theo dõi động lực sử dụng trung bình động Hull làm chỉ số chính để xác định hướng xu hướng giá. Đồng thời, chiến lược kết hợp các chỉ số khác như đường cơ sở, chỉ số xác nhận, vv để xác minh xu hướng giá và lọc các tín hiệu sai. Sau khi vào thị trường, chiến lược sử dụng phạm vi trung bình thực để tính toán stop loss động để theo dõi xu hướng kiếm lợi nhuận.

Nguyên tắc chiến lược

Trọng tâm của chiến lược theo dõi đà là trung bình chuyển động Hull. Trung bình chuyển động Hull nhạy cảm hơn với sự thay đổi giá và có thể xác định hiệu quả hướng xu hướng. Khi giá vượt qua đường Hull lên, một xu hướng tăng được xác nhận, đi dài; khi giá vượt qua đường Hull xuống, một xu hướng giảm được xác nhận, đi ngắn.

Ngoài ra, chiến lược cũng giới thiệu một chỉ số đường cơ sở để đánh giá xu hướng ngắn hạn và dài hạn; một chỉ số xác nhận được sử dụng để lọc các sự đột phá sai.

Sau khi vào thị trường, chiến lược sử dụng phạm vi trung bình thực sự và Hull EMA để thiết lập vị trí dừng lỗ. Khi xu hướng tiếp tục, đường dừng lỗ sẽ tiếp tục di chuyển lên / xuống để khóa lợi nhuận xu hướng.

Phân tích lợi thế

Chiến lược Momentum Tracking kết hợp các lợi thế của việc đánh giá xu hướng và kiểm soát rủi ro, có thể đạt được lợi nhuận tốt trong các thị trường xu hướng.

Sự kết hợp của nhiều chỉ số cũng làm cho chiến lược nhạy cảm hơn với những thay đổi của thị trường, trong khi lọc hiệu quả các tín hiệu sai. Ngoài ra, chiến lược cũng cung cấp nhiều tham số điều chỉnh để người dùng tối ưu hóa dựa trên đánh giá thị trường của riêng họ.

Phân tích rủi ro

Chiến lược dựa chủ yếu trên các chỉ số xu hướng và có xu hướng tạo ra tín hiệu sai và dừng lỗ trong quá trình hợp nhất. Ngoài ra, sự kết hợp của nhiều chỉ số cũng có thể dẫn đến xung đột giữa các chỉ số. Cài đặt tham số không chính xác cũng có thể dẫn đến hiệu suất chiến lược kém.

Xem xét thêm một mô-đun đánh giá bổ sung trong chiến lược để tạm dừng giao dịch khi các chỉ số cho thấy sự khác biệt; hoặc áp dụng một cơ chế bỏ phiếu để tổng hợp kết quả đánh giá của nhiều chỉ số. Đối với cài đặt tham số, các tham số tối ưu có thể được tìm thấy thông qua các phương pháp tối ưu hóa backtest.

Hướng dẫn tối ưu hóa

Chiến lược theo dõi đà có thể được tối ưu hóa theo các hướng sau:

  1. Tăng các mô-đun phán đoán, chẳng hạn như mô-đun biến động, tạm dừng giao dịch khi biến động cao;
  2. Tăng mô-đun học máy, sử dụng thuật toán học máy để xác định trọng lượng chỉ số;
  3. Tối ưu hóa các thông số chỉ số để tìm ra sự kết hợp thông số tốt nhất;
  4. Tối ưu hóa thuật toán dừng lỗ chuyển động để theo dõi xu hướng tốt hơn;
  5. Thêm các mô-đun quản lý rủi ro như dừng lỗ, điều chỉnh vị trí động, v.v.

Tóm lại

Tóm lại, chiến lược Momentum Tracking là một chiến lược theo dõi xu hướng tuyệt vời. Nó kết hợp thành công phán đoán xu hướng và dừng lỗ động, có thể theo dõi và kiếm lợi nhuận hiệu quả từ xu hướng. Với tối ưu hóa hơn nữa, nó dự kiến sẽ đạt được hiệu suất chiến lược tốt hơn. Chiến lược cung cấp một tham chiếu tốt cho việc xây dựng các chiến lược giao dịch định lượng.

/*backtest
start: 2023-11-28 00:00:00
end: 2023-12-28 00:00:00
period: 1h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// © Milleman
//@version=4
strategy("MilleMachine", overlay=true, default_qty_type = strategy.percent_of_equity, default_qty_value = 100, initial_capital=10000, commission_type=strategy.commission.percent, commission_value=0.06)


// Additional settings
Mode = input(title="Mode", defval="LongShort", options=["LongShort", "OnlyLong", "OnlyShort","Indicator Mode"])
UseTP = false                               //input(false, title="Use Take Profit?")
QuickSwitch = true                          //input(true, title="Quickswitch")
UseTC = true                                //input(true, title="Use Trendchange?")

// Risk management settings
//Spacer2 = input(false, title="======= Risk management settings =======")
Risk = input(1.0, title="% Risk",minval=0)/100
RRR = 2                                     //input(2,title="Risk Reward Ratio",step=0.1,minval=0,maxval=20)
SL_Mode = false                             // input(true, title="ON = Fixed SL / OFF = Dynamic SL (ATR)")
SL_Fix = 3                                  //input(3,title="StopLoss %",step=0.25, minval=0)/100
ATR = atr(14)                               //input(14,title="Periode ATR"))
Mul = input(2,title="ATR Multiplier",step=0.1)
xATR = ATR * Mul
SL = SL_Mode ? SL_Fix : (1 - close/(close+xATR))

// INDICATORS  //////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
Ind(type, src, len) =>
    float result = 0
    if type=="McGinley"
        result := na(result[1]) ? ema(src, len) : result[1] + (src - result[1]) / (len * pow(src/result[1], 4))
    if type=="HMA"
        result := wma(2*wma(src, len/2)-wma(src, len), round(sqrt(len)))
    if type=="EHMA"
        result := ema(2*ema(src, len/2)-ema(src, len), round(sqrt(len)))
    if type=="THMA"
        lend = len/2
        result := wma(wma(src, lend/3)*3-wma(src, lend/2)-wma(src,lend), lend)
    if type=="SMA" // Simple
        result := sma(src, len)
    if type=="EMA" // Exponential
        result := ema(src, len)
    if type=="DEMA" // Double Exponential
        e = ema(src, len)
        result := 2 * e - ema(e, len)
    if type=="TEMA" // Triple Exponential
        e = ema(src, len)
        result := 3 * (e - ema(e, len)) + ema(ema(e, len), len)
    if type=="WMA" // Weighted
        result := wma(src, len)
    if type=="VWMA" // Volume Weighted
        result := vwma(src, len) 
    if type=="SMMA" // Smoothed
        w = wma(src, len)
        result := (w[1] * (len - 1) + src) / len
    if type == "RMA"
        result := rma(src, len)
    if type=="LSMA" // Least Squares
        result := linreg(src, len, 0)
    if type=="ALMA" // Arnaud Legoux
        result := alma(src, len, 0.85, 6)
    if type=="Kijun" //Kijun-sen
        kijun = avg(lowest(len), highest(len))
        result :=kijun
    if type=="WWSA" // Welles Wilder Smoothed Moving Average
        result := nz(result[1]) + (close -nz(result[1]))/len
    result

// Baseline : Switch from Long to Short and vice versa
BL_Act = input(true, title="====== Activate Baseline - Switch L/S ======")
BL_type = input(title="Baseline Type", defval="McGinley", options=["McGinley","HMA","EHMA","THMA","SMA","EMA","DEMA","TEMA","WMA","VWMA","SMMA","RMA","LSMA","ALMA","Kijun","WWSA"])
BL_src = input(close, title="BL source")
BL_len = input(50, title="BL length", minval=1)
BL = Ind(BL_type,BL_src, BL_len)

// Confirmation indicator
C1_Act = input(false, title="===== Activate Confirmation indicator =====")
C1_type = input(title="C1 Entry indicator", defval="SMA", options=["McGinley","HMA","EHMA","THMA","SMA","EMA","DEMA","TEMA","WMA","VWMA","SMMA","RMA","LSMA","ALMA","Kijun","WWSA"])
C1_src = input(close, title="Source")
C1_len = input(5,title="Length", minval=1)
C1 = Ind(C1_type,C1_src,C1_len)

// Entry indicator : Hull Moving Average
Spacer5 = input(true, title="====== ENTRY indicator =======")
EI_type = input(title="EI Entry indicator", defval="HMA", options=["McGinley","HMA","EHMA","THMA","SMA","EMA","DEMA","TEMA","WMA","VWMA","SMMA","RMA","LSMA","ALMA","Kijun","WWSA"])
EI_src = input(close, title="Source")
EI_Len = input(46,title="Length", minval=1)
EI = Ind(EI_type,EI_src,EI_Len)

// Trail stop settings
TrailActivation = input(true, title="===== Activate Trailing Stop =====")
TS_type = input(title="TS Traling Stop Type", defval="EMA", options=["McGinley","HMA","EHMA","THMA","SMA","EMA","DEMA","TEMA","WMA","VWMA","SMMA","RMA","LSMA","ALMA","Kijun","WWSA"])
TrailSLScaling = 1 //input(100, title="SL Scaling", minval=0, step=5)/100
TrailingSourceLong = Ind(TS_type,low,input(5,"Smoothing Trail Long EMA", minval=1))
TrailingSourceShort = Ind(TS_type,high,input(2,"Smoothing Trail Short EMA", minval=1))

//VARIABLES MANAGEMENT
TriggerPrice = 0.0, TriggerPrice := TriggerPrice[1]
TriggerSL = 0.0, TriggerSL := TriggerSL[1]
SLPrice = 0.0, SLPrice := SLPrice[1], TPPrice = 0.0, TPPrice := TPPrice[1]
isLong = false, isLong := isLong[1], isShort = false, isShort := isShort[1]

//LOGIC
GoLong = crossover(EI,EI[1]) and (strategy.position_size == 0.0 and QuickSwitch) and (not BL_Act or BL/BL[1] > 1) and (not C1_Act or C1>C1[1]) and (Mode == "LongShort" or Mode == "OnlyLong")
GoShort = crossunder(EI,EI[1]) and (strategy.position_size == 0.0 and QuickSwitch) and (not BL_Act or BL/BL[1] < 1) and (not C1_Act or C1<C1[1]) and (Mode == "LongShort" or Mode == "OnlyShort")
ExitLong = isLong and crossunder(EI,EI[1]) and UseTC
ExitShort = isShort and crossover(EI,EI[1]) and UseTC

//FRAMEWORK
//Reset Long-Short memory
if isLong and strategy.position_size == 0.0
    isLong := false
if isShort and strategy.position_size == 0.0
    isShort := false
//Long
if GoLong
    isLong := true, TriggerPrice := close, TriggerSL := SL
    TPPrice := UseTP? TriggerPrice * (1 + (TriggerSL * RRR)) : na
    SLPrice := TriggerPrice * (1-TriggerSL)
    Entry_Contracts = strategy.equity * Risk / ((TriggerPrice-SLPrice)/TriggerPrice) / TriggerPrice
    strategy.entry("Long", strategy.long, comment=tostring(round((TriggerSL/TriggerPrice)*1000)), qty=Entry_Contracts)
    strategy.exit("TPSL","Long", limit=TPPrice, stop=SLPrice)
if isLong
    NewValSL = TrailingSourceLong * (1 - (SL*TrailSLScaling))
    if TrailActivation and NewValSL > SLPrice
        SLPrice := NewValSL
    strategy.exit("TPSL","Long", limit=TPPrice, stop=SLPrice)
if ExitLong
    strategy.close_all(comment="TrendChange")
    isLong := false

//Short
if GoShort
    isShort := true, TriggerPrice := close, TriggerSL := SL
    TPPrice := UseTP? TriggerPrice * (1 - (TriggerSL * RRR)) : na
    SLPrice := TriggerPrice * (1 + TriggerSL)
    Entry_Contracts = strategy.equity * Risk / ((SLPrice-TriggerPrice)/TriggerPrice) / TriggerPrice
    strategy.entry("Short", strategy.short, comment=tostring(round((TriggerSL/TriggerPrice)*1000)), qty=Entry_Contracts)
    strategy.exit("TPSL","Short", limit=TPPrice, stop=SLPrice)
if isShort
    NewValSL = TrailingSourceShort * (1 + (SL*TrailSLScaling))
    if TrailActivation and NewValSL < SLPrice
        SLPrice := NewValSL
    strategy.exit("TPSL","Short", limit=TPPrice, stop=SLPrice)
if ExitShort
    strategy.close_all(comment="TrendChange")
    isShort := false

//VISUALISATION
plot(BL_Act?BL:na, color=color.blue,title="Baseline")
plot(C1_Act?C1:na, color=color.yellow,title="confirmation Indicator")
EIColor = EI>EI[1] ? color.green : color.red
Fill_EI = plot(EI, color=EIColor, linewidth=1, transp=40, title="Entry Indicator EI")
Fill_EID = plot(EI[1], color=EIColor, linewidth=1, transp=40, title="Entry Indicator EID")
fill(Fill_EI,Fill_EID, title="EI_Fill", color=EIColor,transp=50)

plot(strategy.position_size != 0.0 and (isLong or isShort) ? TriggerPrice : na, title="TriggerPrice", color=color.yellow, style=plot.style_linebr)
plot(strategy.position_size != 0.0 and (isLong or isShort) ? TPPrice : na, title="TakeProfit", color=color.green, style=plot.style_linebr)
plot(strategy.position_size != 0.0 and (isLong or isShort) ? SLPrice : na, title="StopLoss", color=color.red, style=plot.style_linebr)
bgcolor(isLong[1] and cross(low,SLPrice) and low[1] > SLPrice and TriggerPrice>SLPrice ? color.yellow : na, transp=75, title="SL Long")
bgcolor(isShort[1] and cross(high,SLPrice) and high[1] < SLPrice and TriggerPrice<SLPrice ? color.yellow : na, transp=75, title="SL Short")
Thêm nữa

2019 FMZ - Tất cả các quyền được bảo lưu