Estratégia de negociação multi-tempo da P-Signal

Autora:ChaoZhang, Data: 2023-11-28 16:32:36
Tags:

Resumo

A estratégia de negociação multi-frame de tempo P-Signal é uma estratégia de negociação algorítmica de criptomoedas baseada em princípios estatísticos e análise de multi-frame de tempo.

Estratégia lógica

O indicador central da estratégia do sinal-P é o próprio sinal-P, que combina desvio padrão estatístico e média móvel simples e o mapeia para o intervalo de -1 a 1 usando a função de erro de Gauss, para detectar se o mercado está em conformidade com a distribuição normal.

fErf(x) = 1.0 - 1.0/(1.0 + 0.5*abs(x)) * exp(-x*x - 1.26551223 + ...) # Gaussian error function 

fPSignal(ser, n) = fErf((stdev(ser, n) > 0 ? sma(ser, n)/stdev(ser, n)/sqrt(2) : 1)) # P-Signal indicator

A estratégia calcula o indicador P-Signal nos prazos diários, semanais e mensais para o Bitcoin, vai longo quando o indicador cruza acima de 0, e sai quando cruza abaixo de 0. As válvulas de valor do indicador também são definidas para controlar entradas repetidas.

Análise das vantagens

A maior vantagem da estratégia P-Signal é o uso de vários prazos para melhorar a estabilidade da estratégia. O gráfico diário capta flutuações de curto prazo do mercado, enquanto os gráficos semanais e mensais filtram falhas.

Em comparação com um único prazo, vários prazos permitem o uso de paradas diárias para controlar o drawdown durante períodos voláteis, reduzindo a frequência de transações usando os prazos mais altos durante os mercados variáveis.

Análise de riscos

O maior risco da estratégia P-Signal é que o próprio indicador é uma caixa preta para os traders quant. Nós não temos nenhuma maneira de determinar a adaptabilidade deste indicador para mercados específicos, nem podemos determinar a faixa ideal de seus parâmetros. Isso pode levar a um mau desempenho da estratégia na negociação ao vivo.

Além disso, a estratégia em si tem algumas limitações. Por exemplo, incapacidade de lidar com movimentos violentos, sinal atrasado de cruzamento de indicadores, etc. Tudo isso pode se tornar problemas ocultos durante a negociação ao vivo.

Para resolver esses problemas, podemos ajustar os parâmetros do indicador, otimizar o stop loss, introduzir mais indicadores auxiliares, etc. Mas a premissa é testar a estabilidade em períodos de backtesting suficientemente grandes.

Orientações de otimização

Existem várias direcções para otimizar a estratégia P-Signal:

Alteração dos parâmetros do indicador de sinal P: nIntr_D, nIntr_W e nIntr_M, encontrar combinações ótimas de parâmetros
Adicionar métodos de stop loss: trailing stop loss, time stop loss, ATR stop loss etc, encontrar o máximo stop loss
Introduzir indicadores auxiliares: melhorar o julgamento das condições específicas do mercado, por exemplo, utilizar o MACD para determinar as tendências
Otimizar o dimensionamento da posição: definir dimensionamento dinâmico da posição com base na eficiência de utilização da conta
Optimização do aprendizado de máquina: usar redes neurais, algoritmos genéticos para encontrar parâmetros globalmente ideais

Conclusão

A estratégia de negociação multi-tempo do P-Signal é, em geral, uma idéia de estratégia muito promissora. Ele combina princípios estatísticos e indicadores técnicos, e usa análise multi-tempo para melhorar a estabilidade.

/*backtest
start: 2022-11-21 00:00:00
end: 2023-11-27 00:00:00
period: 1d
basePeriod: 1h
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/

// **********************************************************************************************************
// This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
// P-Signal Strategy © Kharevsky
// A good strategy should be able to handle backtesting.
// @version=4
// **********************************************************************************************************
strategy("P-Signal Strategy:", precision = 3, pyramiding = 3)
//
// Parameters and const of P-Signal.
//
nPoints_D = input(title = "Number of D Bars", type = input.integer, defval = 9, minval = 4, maxval = 100, group = "Parameters of observation.")
nPoints_W = input(title = "Number of W Bars", type = input.integer, defval = 4, minval = 4, maxval = 100, group = "Parameters of observation.")
nPoints_M = input(title = "Number of M Bars", type = input.integer, defval = 6, minval = 4, maxval = 100, group = "Parameters of observation.")
int nIntr_D = nPoints_D - 1
int nIntr_W = nPoints_W - 1
int nIntr_M = nPoints_M - 1
bool bDValveOpen = true
bool bWValveOpen = true
bool bMValveOpen = true
// 
// Horner's method for the error (Gauss) & P-Signal functions.
//
fErf(x) =>
    nT = 1.0/(1.0 + 0.5*abs(x))
    nAns = 1.0 - nT*exp(-x*x - 1.26551223 + 
     nT*( 1.00002368 + nT*( 0.37409196 + nT*( 0.09678418 + 
     nT*(-0.18628806 + nT*( 0.27886807 + nT*(-1.13520398 + 
     nT*( 1.48851587 + nT*(-0.82215223 + nT*( 0.17087277 ))))))))))
    x >= 0 ? nAns : -nAns
fPSignal(ser, int) => 
    nStDev = stdev(ser, int)
    nSma = sma(ser, int)
    fErf(nStDev > 0 ? nSma/nStDev/sqrt(2) : 1.0)
//
// Signals for the strategy.
//
float nPSignal_D = sma(fPSignal(change(ohlc4), nIntr_D), nIntr_D)
float ndPSignal_D = sign(nPSignal_D[0] - nPSignal_D[1])
//
float nPSignal_W = sma(security(syminfo.tickerid, "W",fPSignal(change(ohlc4), nIntr_W)), nIntr_W)
float ndPSignal_W = sign(nPSignal_W[0] - nPSignal_W[1])
//
float nPSignal_M = sma(security(syminfo.tickerid, "M",fPSignal(change(ohlc4), nIntr_M)), nIntr_M)
float ndPSignal_M = sign(nPSignal_M[0] - nPSignal_M[1])
//
// P-Signal plotting. 
//
hline(+1.0, color = color.new(color.orange,70), linestyle = hline.style_dotted)
hline(-1.0, color = color.new(color.orange,70), linestyle = hline.style_dotted)
plot(nPSignal_D, color = color.blue, style = plot.style_line)
//
// Multi Frame Strategy 
// ... Day
if(nPSignal_D < 0 and ndPSignal_D > 0 and bDValveOpen)
    strategy.entry("long_D", strategy.long, 1) 
    bDValveOpen := false
if(nPSignal_D > 0 and ndPSignal_D < 0)
    strategy.close("long_D")
    bDValveOpen := true
// ... Week
if(nPSignal_W < 0 and ndPSignal_W > 0 and bWValveOpen)
    strategy.entry("long_W", strategy.long, 1) 
    bWValveOpen := false
if(nPSignal_W > 0 and ndPSignal_W < 0)
    strategy.close("long_W")
    bWValveOpen := true
// ... Month
if(nPSignal_M < 0 and ndPSignal_M > 0 and bMValveOpen)
    strategy.entry("long_M", strategy.long, 1) 
    bMValveOpen := false
if(nPSignal_M > 0 and ndPSignal_M < 0)
    strategy.close("long_M")
    bMValveOpen := true
// The end.

Mais.