Estratégia de negociação quantitativa baseada no indicador de momento de compressão LazyBear
ChaoZhang
Visão geral
Esta estratégia é baseada no indicador de volume de compressão do LazyBear, com a adição de um filtro de volume de compressão, a alteração da fonte de dados e a adição de um sistema de gerenciamento de risco com um período de tempo de retrospecção personalizado, destinado a capturar explosões de preços após a compressão de volatilidade.
Princípio da estratégia
A estratégia usa o indicador de correia de Brin e o indicador de canal de Keltner para calcular o canal de preço, que é visto como um sinal de aumento de volatilidade quando o preço atravessa o canal. Ele combina o indicador de compressão de LazyBear, que usa o método de regressão linear para determinar a direção do movimento de preço.
A estratégia inclui um filtro de momentum, que emite um sinal de negociação somente quando o valor absoluto do momentum excede o limiar. Quando a compressão de volatilidade (a aperto no canal) e o filtro de momentum são passados, a estratégia determina a direção da tendência, faz mais ou faz menos. Ao mesmo tempo, configura um stop loss, um stop loss e um stop loss tracking para controlar o risco.
Análise de vantagens
A estratégia integra vários critérios de avaliação de indicadores, é mais abrangente; a inclusão de mecanismos de gerenciamento de risco, que pode limitar os perdas individuais; a direção da tendência de preços pode ser determinada em tempo hábil após a compressão da volatilidade; os parâmetros podem ser personalizados e são adaptáveis.
Análise de Riscos
Os principais riscos são: Falso breakout leva a um erro de julgamento; Parâmetros de configuração incorreta, não reverter o tempo; Stop Loss é causado por breakout expansão de perdas. Você pode otimizar os parâmetros, ajustar os parâmetros de gerenciamento de risco, escolher a variedade adequada e período de negociação para reduzir esses riscos.
Direção de otimização
Pode-se considerar a combinação de outros indicadores de filtragem de sinais, como o indicador de volume de transação; ajustar o valor de queda do volume de transação com mais precisão; definir um stop-loss de retirada para controlar ainda mais o risco; testar mais variedades de efeitos de dados. Essas otimizações podem tornar a estratégia mais estável e generalizada.
Resumir
Esta estratégia é mais abrangente para avaliar a tendência e a volatilidade dos preços, tem um alto grau de integração, as medidas de controle de risco são mais completas, podem ser melhoradas de acordo com a direção de otimização e têm uma forte adaptabilidade às explosões de preços após a captura da compressão da volatilidade.
/*backtest
start: 2024-01-05 00:00:00
end: 2024-02-04 00:00:00
period: 2h
basePeriod: 15m
exchanges: [{"eid":"Futures_Binance","currency":"BTC_USDT"}]
*/
// @version=4
// Strategy based on LazyBear Squeeze Momentum Indicator
// © Bitduke
// All scripts: https://www.tradingview.com/u/Bitduke/#published-scripts
strategy(shorttitle="SMS", title="Squeeze Momentum Strategy", overlay=false )
length = input(12, title="BB Length")
mult = input(2.0, title="BB MultFactor")
lengthKC = input(16, title="KC Length")
mult_kc = input(1.5, title="KC MultFactor")
//FILTERS
useMomAverage = input(false, title="Filter for Momenutum value", type=input.bool)
MomentumMin = input(20, title="Min for momentum")
// Calculate BB
src = ohlc4
ma_1 = sma(src, length)
ma_2 = sma(src, lengthKC)
range_ma = sma(high - low, lengthKC)
dev = mult * stdev(src, length)
upper_bb = ma_1 + dev
lower_bb = ma_1 - dev
upper_kc = ma_2 + range_ma * mult_kc
lower_kc = ma_2 - range_ma * mult_kc
sqz_on = lower_bb > lower_kc and upper_bb < upper_kc
sqz_off = lower_bb < lower_kc and upper_bb > upper_kc
no_sqz = sqz_on == false and sqz_off == false
val = linreg(src - avg(avg(highest(hl2, lengthKC), lowest(low, lengthKC)), sma(hl2, lengthKC)), lengthKC, 0)
bcolor = iff(val > 0, iff(val > nz(val[1]), color.lime, color.green), iff(val < nz(val[1]), color.red, color.maroon))
scolor = no_sqz ? color.blue : sqz_on ? color.black : color.aqua
plot(val, color=bcolor, style=plot.style_histogram, linewidth=4)
plot(0, color=scolor, style=plot.style_cross, linewidth=2)
//LOGIC
//momentum filter
filterMom = useMomAverage ? abs(val) > MomentumMin / 100000 ? true : false : true
//standard condition
longCondition = scolor[1] != color.aqua and scolor == color.aqua and bcolor == color.lime and filterMom
exitLongCondition = bcolor == color.green
shortCondition = scolor[1] != color.aqua and scolor == color.aqua and bcolor == color.red and filterMom
exitShortCondition = bcolor == color.maroon
// Risk Management Sysyem
stop_loss = input(defval = 600, title="Stop Loss", minval = 0)
take_profit = input(defval = 1000, title="Take Profit", minval = 0)
trailing_stop = input(defval = 20, title="Trailing Stop", minval = 0)
// If the zero value is set for stop loss, take profit or trailing stop, then the function is disabled
s_loss = stop_loss >= 1 ? stop_loss : na
tk_profit = take_profit >= 1 ? take_profit : na
tr_stop = trailing_stop >= 1 ? trailing_stop : na
//STRATEGY
strategy.entry("SQ_Long", strategy.long, when=longCondition)
strategy.exit("Exit Long", from_entry = "SQ_Long", profit = take_profit, trail_points = trailing_stop, loss = s_loss)
strategy.close("SQ_Long", exitLongCondition)
strategy.entry("SQ_Short", strategy.short, when=shortCondition)
strategy.exit("Exit Short", from_entry = "SQ_Short", profit = take_profit, trail_points = trailing_stop, loss = s_loss )
strategy.close("SQ_Short", when=exitShortCondition)